USART

NOTA: El código no utiliza las definiciones del archivo inc.

Si has leído los tutoriales anteriores lo más seguro es que ya te acostumbraste y ya no lo necesites, pero de todas maneras a la derecha dejo el nombre del registro correspondiente.

Por parte de la aplicación vamos a hacer el típico "hola mundo" pero en forma digital, esto es, encender y apagar un led mediante bluetooth.

Empezamos por configurar y calibrar el reloj interno.

;Configurando el reloj a 8MHZ
bsf 0x08,0 ;Banco 1
movlw 0x72
movwf 0x99 ;OSCCON
btfss 0x9A,4;OSCSTAT
goto $-1
btfss 0x9A,3
goto $-1
btfss 0x9A,0
goto $-1


Una de las características de la serie 182X, es la posibilidad de modificar el funcionamiento de ciertos pines.

En este caso los pines que nos interesan son los correspondientes a la USART, por parte del receptor Rx puede ser RB1 o RB2 y el transmisor Tx puede ser RB2 o RB5, pues bueno, voy a dejar Rx en RB1 y Tx en RB2 por lo tanto no es necesaria ninguna configuración adicional por default ya están configurados de esta manera.

;Configurando puertos
clrf 0x8C ;TRISA
clrf 0x8D ;TRISB
bsf 0x08,1 ;Banco 3
clrf 0x18C ;ANSELA
clrf 0x18D ;ANSELB


Ahora vamos a configurar el modulo EUSART en modo transmisión/recepción asíncrono UART.
El fabricante del modulo bluetooth nos da las siguientes especificaciones:

Default Baud rate: 38400, Data bits:8, Stop bit:1,Parity:No parity, Data control: has.
Supported baud rate: 9600,19200,38400,57600,115200,230400,460800.

Yo lo voy a utilizar en 9600:N:8:1 (Baud rate:9600, Parity: No parity, Data bits: 8 bits, Stop bit: 1)

En las hojas de datos podemos encontrar la formula para calcular el valor de los registros SPBRGH y SPBRGL, así como la tabla para los bits BRGH y BRG16, pero al menos que estés utilizando un baudaje especifico la manera mas rápida y cómoda es utilizar la tabla de valores que te proporciona microchip.

En la tabla de la hoja de datos vienen muchos datos y tal vez no sabes cual elegir, pero no te preocupes es más fácil de lo que crees, en primer lugar nos fijamos en el tipo de transmisión, en este caso es asíncrono, luego buscamos nuestra frecuencia de trabajo Fosc, en este caso son 8Mhz, por último el baudaje que queremos, en este caso son 9600, si ves que en todos los parámetros sale una raya "--", eso quiere decir que la frecuencia de trabajo no soporta ese baudaje o bien tienes que modificar los bits BRGH y BRG16.
Para que sirva de ejemplo busca en la imagen de arriba la frecuencia de 8Mhz para transmitir a 9600, la tabla especifica lo siguiente:
• Actual Rate: 9615
• % Error: 0.16
• SPBRG value: 12
Muy bien esto quiere decir que con 8Mhz solo podemos transmitir a 9615 bps con un error del 16%, para este caso el error es tolerable no pasa de que el modulo vuelva a mandar el dato, si queremos 0% de error tendríamos que transmitir a 10417 bps.
NOTA: SPBRG = SPBRGH(MSB)+SPBRGL(LSB)
Configuración de los registros:
• Sync = 0.
• BRGH = 0.
• BRG16 = 0.
Estos serian los valores de los registros que tenemos que poner en la configuración de la EUSART para que transmita a 9600bps.

;Configurando EUSART
movlw .12 ;Valor encontrado en tablas
movwf 0x19B ;SPBRGL
bsf 0x19D,7 ;RCSTA (SPEN=1)
bsf 0x19D,4 ;RCSTA (CREN=1)
bsf 0x19E,5 ;TXSTA (TXEN=1)


Por último configuramos la interrupción de recepción para atender cuando queramos encender, apagar o saber el estado del led.

;Configurando interrupciones
bcf 0x08,1 ;Banco 1
bsf 0x91,5 ;PIE1 (RCIE)
movlw 0xC0
movwf 0x0B ;INTCON


Con esto queda configurado el modulo EUSART, antes de seguir adelante debemos atener algo primero, el modulo por defecto se llama HC-05, si por algún motivo alguien hace un barrido con su celular o computadora y ve este nombre puede ser que sepa la contraseña, la cual es 1234, si la sabe ganaría acceso a nuestro microcontrolador, ya solo necesita saber los comandos para prender y apagar el led sin nuestro consentimiento, por lo tanto es vital cambiar tanto el nombre como la contraseña, o por lo menos el nombre.
El modulo se configura mediante comandos AT, pero para poder entrar en modo de comandos hay que hacer lo siguientes paso tal cual los pongo:

IMPORTANTE: El modulo utiliza 3.3 Volts por lo tanto no lo conectes a pines cuya salida sea de 5V, si lo haces es posible que se dañe el modulo de comunicación.

• Poner en bajo el PIN34.
• Encender la fuente.
• Poner en alto el PIN34.

Si compraste el modulo por ebay, o alguna otra tienda, estos vienen con un microswitch, si este es tu caso has lo siguiente:

• Manten presionado el switch.
• Enciende la fuente.
• Deja de presionar el switch.

Si lo hiciste bien el led (PIN31) debe parpadear aproximadamente a 1Hz mientras que en modo normal parpadea a 2Hz.
Lo que no indican (al menos en la hoja de datos que tengo) son los tiempo de espera, yo intente mandar el dato una solo vez pero no conseguía configurar el modulo, por lo tanto hice un bucle y lo deje alrededor de 5 segundos y ya quedo configurado.
Podría hacer una interfaz ASCII para configurar el modulo pero como solo tengo planeado configurarlo una sola vez la verdad no le veo el caso, que claro, si lo van a estar configurando cada cierto tiempo tal vez si les convenga crear una interfaz mas amigable y no hacerlo mediante fuerza bruta como yo lo hice.

;Configurando el modulo
;Cambiando de nombre al modulo
movlw 0x03
movwf 0x08 ;Banco 3
Loop clrf 0x1A0 ;Indice
AT movf 0x1A0,0
call _AT
movwf 0x19A ;TXREG
btfss 0x19E,1
goto $-1
incf 0x1A0,1
movf 0x1A0,0
xorlw .19
btfss 0x03,2
goto AT 
goto Loop
_AT addwf 0x02,1
dt "AT+NAME=edx-Twin3",0x0D,0x0A


IMPORTANTE: Todos los comandos deben terminar con \r\n = 0x0D 0x0A Para el caso del password es lo mismo, solo cambien en _AT la cadena AT+NAME=edx-twin3 por AT+PSWD=SU_PASSWORD.
Aquí les dejo la hoja de datos con todos los comandos:HC-05.pdf

Una vez que cambiamos el nombre y password del modulo, hacemos la rutina de atención a la interrupción.

org 0x04
movlw 0x03
movwf 0x08 ;Banco 3
movf 0x199,0 ;(RCREG)
movwf 0x1A0
movlw 0x41 ;(A)
xorwf 0x1A0,0
btfss 0x03,2
goto $+2
goto apagar
movlw 0x45 ;(E)
xorwf 0x1A0,0
btfss 0x03,2
goto $+2
goto encender
movlw 0x53 ;(S)
xorwf 0x1A0,0
btfss 0x03,2
goto salida
goto estado
apagar movlw 0x02
movwf 0x08
bcf 0x10D,3
goto salida 

encender movlw 0x02
movwf 0x08
bsf 0x10D,3
goto salida

estado clrf 0x08
btfss 0x0D,3
goto CERO
goto UNO

UNO movlw 0x03
movwf 0x08
clrf 0x1A0
loop movf 0x1A0,0
call _UNO
movwf 0x19A ;TXREG
btfss 0x19E,1
goto $-1
incf 0x1A0,1
movf 0x1A0,0
xorlw 0x0B
btfss 0x03,2
goto loop
goto salida

_UNO addwf 0x02,1
dt "Encendido",0x0D,0x0A

CERO movlw 0x03
movwf 0x08
clrf 0x1A0
loop1 movf 0x1A0,0
call _CERO
movwf 0x19A ;TXREG
btfss 0x19E,1
goto $-1
incf 0x1A0,1
movf 0x1A0,0
xorlw 0x09
btfss 0x03,2
goto loop1
goto salida

_CERO addwf 0x02,1
dt "Apagado",0x0D,0x0A

salida bcf 0x11,5 ;PIR1 (RCIF=0)
retfie

Por último el programa principal.

goto $+0